File:Blue 7 1 Knot.png

Original file(1,800 × 1,800 pixels, file size: 520 KB, MIME type: image/png)

Captions

Captions

Add a one-line explanation of what this file represents
 
This image was created with POV-Ray.

Summary

edit
Description
English: A 7₁ knot.
Source Own work
Author Jim.belk

Licensing

edit
Public domain I, the copyright holder of this work, release this work into the public domain. This applies worldwide.
In some countries this may not be legally possible; if so:
I grant anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law.

Source

edit

This image was created using POV-Ray for Windows, version 3.6. The image was rendered to an 1800 x 1800 square, using 0.3 anti-aliasing.

#include "colors.inc"
    
background { color White }

global_settings { assumed_gamma 1.0}

camera
  {
  location <0, 0, -25>
  right <1,0,0> up <0,1,0>
  look_at  <0, 0, 0>
  angle 5
  }


light_source
  {
  <0, 20, -50>
  color White
  area_light <5, 0, 0>, <0, 5, 0>, 10, 10  /* very slow, decrease 10 to 2 for experiments */
  adaptive 3
  }

  
#declare r_tube = 0.05;
#declare num_steps = 70;
#declare step_size = 1/num_steps;
              

sphere_sweep
  {
  cubic_spline num_steps+3,
  #declare N = -1;
  #while(N <= num_steps + 1)
    #declare theta = 2 * pi * N * step_size;
    <0.3*( (7/3)*sin(2*theta)*(1+(2/7)*cos(7*theta)) ), 0.3*( (7/3)*cos(2*theta)*(1+(2/7)*cos(7*theta)) ), 0.2*sin(7*theta)>, r_tube
    /* uses a hypotrochoid */
    #declare N = N + 1;
  #end
  pigment { color rgb <0,0.25,1> }
  finish          
    {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.3
    phong_size 10
    }
  }

plane
  {
  <0,0,-1>, -0.25
  pigment { color White }
  finish
    {
    ambient 0.35
    diffuse 0.65
    }
  }

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current17:55, 5 July 2015Thumbnail for version as of 17:55, 5 July 20151,800 × 1,800 (520 KB)Cmdrjameson (talk | contribs)Compressed with pngout. Reduced by 503kB (49% decrease).
17:56, 22 March 2010Thumbnail for version as of 17:56, 22 March 20101,800 × 1,800 (1,023 KB)Jim.belk (talk | contribs){{Information |Description={{en|1=A 7₁ knot.}} |Source={{own}} |Author=Jim.belk |Date= |Permission= |other_versions= }} Category:Knots (knot theory) Category:Images including source code in their description

There are no pages that use this file.

File usage on other wikis

The following other wikis use this file: