DescriptionConvolution Animation (Boxcar and Ramp).gif	English: An animation of the convolution of two functions, f(t) and g(t). ${\displaystyle f(t)=0.7\left[H\left(x+{\frac {1}{4}}\right)-H\left(x-{\frac {1}{4}}\right)\right]}$ ${\displaystyle g(t)={\begin{cases}t,&0\leq t<1\\0,&{\mbox{otherwise}}\end{cases}}}$, where H(x) is the Heaviside step function. Also shown is the time-reversed and shifted g(τ−t) in solid blue, the product f(t)g(τ−t) (green) and the convolution h(t)=f(t) ∗ g(t) (black, equal to the area of the product at the particular τ)
Date	5 March 2009
Source	Own work
Author	Inductiveload
Permission (Reusing this file)	Public domainPublic domainfalsefalse I, the copyright holder of this work, release this work into the public domain. This applies worldwide. In some countries this may not be legally possible; if so: I grant anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law.

Mathematica Code edit

(*Function definitions*)
boxcar[x_, {a_, b_}] := UnitStep[x - a] - UnitStep[x - b];

f[t_] := 0.7*boxcar[t, {-1/4, 1/4}];
g[t_] := Piecewise[
   {{0, t < 0},
    {t, 0 < t < 1},
    {0, t > 1}}];
h[y_] := Module[
   {t},
   Convolve[f[t], g[t], t, y]
   ];

(*Parts of the drawing that only need to be computed once*)
constplots = Plot[
   {f[t], g[t], h[t]},
   {t, -2, 2},
   PlotStyle -> {Red, {Blue, Dashed}, Black},
   ClippingStyle -> False,
   Axes -> False,
   Exclusions -> False
   ];

anim =
  Table[Show[
    {
     (*The plots we generated earlier*)
     constplots,
     
     (*Plot the time reversed g[t], g[\[Tau]-t]*)
     Plot[g[\[Tau] - t],
      {t, -5, 5},
      PlotPoints -> 100,
      ClippingStyle -> False,
      PlotStyle -> Blue,
      Exclusions -> False,
      Axes -> False],
     
     (*Plot the product of the f[t] and g[\[Tau]-t]*)
     Plot[f[t]*g[\[Tau] - t],
      {t, -5, 5},
      PlotPoints -> 100,
      ClippingStyle -> False,
      Filling -> Axis,
      FillingStyle -> Directive[Green, Opacity[0.2]],
      PlotStyle -> Green,
      Exclusions -> False,
      Axes -> False],
     
     (*Plot the embellishments*)
     Graphics[
      {{Blue, Line[{{\[Tau], -0.05}, {\[Tau], 1.1}}]},
       {Red, Text[f, {.2, .76}, Background -> None]},
       {Blue, Text[g, {.48, .55}, Background -> None]},
       {Blue, 
        Text["g(\[Tau]-t)", {\[Tau] - .58, .4}, Background -> None]},
       {Green, 
        Text["f(t)g(\[Tau]-t)", {\[Tau] - 0.55, -0.04}, 
         Background -> None]},
       {Black, Text[Star[f, g], {.65, .15}, Background -> None]},
       {Blue, Text["\[Tau]", {\[Tau], -0.1}, Background -> White]}
       }]
     },
    PlotRange -> {{-1.9, 1.9}, {-.2, 1}}],
   
   {\[Tau], -2, 2, .025}(*Table index is the time delay*)
   ];

ListAnimate[anim]