File:Dipoles and mirrors.gif
No higher resolution available.
Dipoles_and_mirrors.gif (360 × 360 pixels, file size: 1.09 MB, MIME type: image/gif, looped, 34 frames)
Captions
Captions
Field lines of the Poynting vector of a dipole near a mirror.
Summary edit
| Description |
English: If you put an electric dipole near to a mirror (around one wavelength away) the field lines of its Poynting vector (which gives the direction of the energy flux) create complex patterns, including spirals and vortices.
(Reference: doi.org/10.1103/PhysRevA.81.053844) |
| Date | |
| Source | https://twitter.com/j_bertolotti/status/1148164440086523904 |
| Author | Jacopo Bertolotti |
| Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 11.0 code edit
d0 = 1; (*amplitude of the dipole*)
\[Omega] = 1; (*frequency of oscillation of the dipole*)
c = 5; (*speed of light*)
k0 = \[Omega]/c; (*free space wave number*)
q[r_] := k0*Norm[r]; (*unitless position*)
nr[r_] := r/Norm[r]; (*versor of the position*)
\[Epsilon]0 = 1; (*vacuum permittivity*)
\[Mu]0 = 1; (*vacuum permeability*)
Ed[\[Epsilon]_, r_] :=
Module[{\[Epsilon]1}, \[Epsilon]1 = \[Epsilon]/Norm[\[Epsilon]]; (k0^3 d0)/(4 \[Pi] \[Epsilon]0 q[r]) (\[Epsilon]1 - (\[Epsilon]1.nr[r]) nr[r] + (\[Epsilon]1 - 3 (\[Epsilon]1.nr[r]) nr[r]) I/q[r] (1 + I/q[r]) ) E^(I q[r])];
Bd[\[Epsilon]_, r_] := Module[{\[Epsilon]1}, \[Epsilon]1 = \[Epsilon]/Norm[\[Epsilon]]; -((k0^3 d0)/(4 \[Pi] \[Epsilon]0 c q[r])) (Cross[\[Epsilon]1, nr[r]]) (1 + I/q[r]) E^(I q[r])
];
Sd[\[Epsilon]_, r_] := 1/(2 \[Mu]0) Re[Cross[Ed[\[Epsilon], r], Conjugate[Bd[\[Epsilon], r]]] ];
P0 = (c k0^4)/(12 \[Pi] \[Epsilon]0) d0^2;
Sd1[\[Epsilon]_, r_, h_] := (3 P0)/(8 \[Pi] Norm[r]^2) 1/(2 \[Mu]0) Re[Cross[Ed[\[Epsilon], r] + Ed[\[Epsilon]*{-1, -1, 1}, r + {0, 0, 2*h}], Conjugate[Bd[\[Epsilon], r] + Bd[\[Epsilon]*{-1, -1, 1}, r + {0, 0, 2*h}]]] ];
p1 = Table[
StreamPlot[
Sd1[{Cos[\[Theta]], 0, Sin[\[Theta]]}, {x, 0, z}, (2 \[Pi])/k0][[{1, 3}]], {x, -((2 \[Pi])/k0), (2 \[Pi])/k0}, {z, -((2 \[Pi])/k0), (2 \[Pi])/k0}, StreamPoints -> Fine , StreamStyle -> {Black}, Frame -> False, Epilog -> {Blue, Thick, Arrow[{{-3 Cos[\[Theta]], -3 Sin[\[Theta]]}, {3 Cos[\[Theta]], 3 Sin[\[Theta]]}}], Darker[Gray], Thickness[0.01], Line[{{-((2 \[Pi])/k0), -((2 \[Pi])/k0)}, {(2 \[Pi])/k0, -((2 \[Pi])/k0)}}]}], {\[Theta], 0, \[Pi]/2, \[Pi]/32}];
ListAnimate[Join[p1, Reverse[p1]]]
Licensing edit
I, the copyright holder of this work, hereby publish it under the following license:
 
|
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
| The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
|
File history
Click on a date/time to view the file as it appeared at that time.
| Date/Time | Thumbnail | Dimensions | User | Comment | |
|---|---|---|---|---|---|
| current | 09:20, 9 July 2019 | | 360 × 360 (1.09 MB) | Berto (talk | contribs) | User created page with UploadWizard |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
