Summary edit

Data file edit

The double-torus was produced using POV-Ray v3.6 using the following code:

#include "colors.inc"
#include "shapes.inc"   
#include "textures.inc"
#include "functions.inc"

camera
{
       location <-0.5, 3, -2>
       look_at <0, 0, 0>
}

//Striped textures
#declare bluestripes = texture
       {
               pigment
               { 
                       gradient y
                       colour_map{[0 rgb <0,0,1>][0.15 rgb <1,1,1>]}
               }
               scale 0.1
               finish { ambient 0.3 }
               rotate <0,0,90>
       }
       
#declare redstripes = texture
       {
               pigment
               {
                       spiral1 1
                       colour_map{[0 rgb <0.8,0,0>][0.25 rgb <1,1,1>]}
               }
               scale 0.1
               finish { ambient 0.3 }
       }
       
#declare blueredstripes = texture
       {        
               pigment
               {
                       spiral1 1
                       colour_map{[0 rgb <0.8,0,0>][0.25 rgb <1,1,1>]}
               }
               scale 0.1
               finish { ambient 0.3 }   
       }              
       texture
       {
               pigment
               {
                       gradient y
                       colour_map{[0 rgb <0,0,0.8>][0.15 rgb <1,1,1> filter 1]}
               }
               scale 0.1
               finish { ambient 0.3 }
               rotate <0,0,90>  
       }

#declare Blob_threshold=0.0001;

#declare double_torus=isosurface
{
       function        //Smoothed sum of two level surfaces
       {
               (1+Blob_threshold)
               -pow(Blob_threshold,f_torus(x+0.6, y, z, 0.5, 0.2))
               -pow(Blob_threshold,f_torus(x-0.6, y, z, 0.5, 0.2))
       }
       contained_by { box { <-1.5,-0.3,-0.9>, <1.5,0.3,0.9> } }      //Set containing box, default is too small
       max_gradient 15
}

//Red part
object
{        
       double_torus
       clipped_by{plane{-x,-0.15}}
       texture
       {
               redstripes
       }
}

//Blue part
object
{        
       double_torus
       clipped_by{plane{x,-0.15}}
       texture
       {
               bluestripes
       }
}

//Intersection part
object
{        
       double_torus
       clipped_by{plane{x,0.15}}
       clipped_by{plane{-x,0.15}}
       texture
       {
               blueredstripes
       }
}

//Empty background
plane
{
       <0, 1, 0>, -2
       no_image
}                               

light_source { <0, 1.5, -2> color White}

Licensing edit

I, the copyright holder of this work, release this work into the public domain. This applies worldwide. In some countries this may not be legally possible; if so: I grant anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law.