File:Wavefront Shaping.gif
Wavefront_Shaping.gif (360 × 359 pixels, file size: 5.78 MB, MIME type: image/gif, looped, 112 frames, 11 s)
Captions
Summary edit
DescriptionWavefront Shaping.gif |
English: Light passing through a disordered medium is scrambled into a speckle pattern. But by phase delaying parts of the incident wave (i.e. "shaping" the wavefront) we can reconstruct a pretty good focus by having all the scattered waved to interfere constructively at a given point. |
Date | |
Source | https://twitter.com/j_bertolotti/status/1400030467106258947 |
Author | Jacopo Bertolotti |
Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 12.0 code edit
\[Lambda]0 = 1.; k0 = N[(2 \[Pi])/\[Lambda]0]; (*The wavelength in vacuum is set to 1, so all lengths are now in units of wavelengths*)
\[Delta] = \[Lambda]0/20; \[CapitalDelta] = 30*\[Lambda]0; (*Parameters for the grid*)
imn = Table[
Chop[5 (E^-((x + \[CapitalDelta]/2)/d) + E^((x - \[CapitalDelta]/2)/d) + E^-((y + \[CapitalDelta]/2)/d) + E^((y - \[CapitalDelta]/2)/d))], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}]; (*Imaginary part of the refractive index (used to emulate absorbing boundaries)*)
dim = Dimensions[imn][[1]];
ren = Clip[Total[Table[ RotateRight[DiskMatrix[8, dim], {RandomInteger[{-Round[dim/2], Round[dim/2] }], RandomInteger[{ -Round[dim/2]/4, 0}]}], {70}]], {0, 1}] + 1;
d = \[Lambda]0/2; (*typical scale of the absorbing layer*)
L = -1/\[Delta]^2*KirchhoffMatrix[GridGraph[{dim, dim}]]; (*Discretized Laplacian*)
n = ren + I imn;
optimizedpoint = Round[0.8 dim];
sourcelist = Table[x0, {x0, -\[CapitalDelta]/2 + 2, \[CapitalDelta]/2 - 2, 1}];
sourcedim = Dimensions[sourcelist][[1]];
phases = Table[
\[Phi]in = Table[E^(-((x - sourcelist[[j]])^2/(2 (\[Lambda]0/2)^2))) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))), {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];(*Discretized source*)
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
\[Phi] = Partition[LinearSolve[M, b], dim]; (*Solve the linear system*)
Arg[\[Phi][[Round[dim/2] , optimizedpoint ]] ]
, {j, 1, sourcedim, 1}];
frames = Table[
\[Phi]in = Total@Table[ Table[E^(-((x - sourcelist[[j]])^2/(2 (\[Lambda]0/2)^2))) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) E^(-I*t* phases[[j]]), {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}], {j, 1, sourcedim}];(*Discretized source*)
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
\[Phi] = Partition[LinearSolve[M, b], dim]; (*Solve the linear system*)
ImageAdd[
ArrayPlot[Transpose[(Abs[(\[Phi])]^2/Max[(Abs[\[Phi]]^2)[[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]])][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]], ColorFunction -> "AvocadoColors", DataReversed -> True, Frame -> False, PlotRange -> {0, 1}, LabelStyle -> {Black, Bold}, ColorFunctionScaling -> False, Epilog -> {Red, Thick, Table[ Line[{{(k - 1) (dim - (8 d)/\[Delta])/sourcedim, t*5*phases[[k]] + 10}, {k (dim - (8 d)/\[Delta])/sourcedim, t*5*phases[[k]] + 10}}], {k, 1, sourcedim}] }],
ArrayPlot[Transpose@Re[(tmpn - 1)/5] , DataReversed -> True , ColorFunctionScaling -> False, ColorFunction -> GrayLevel, Frame -> False]
]
, {t, 0, 1, 1/40}]
ListAnimate[ Join[Table[frames[[1]], 15], frames, Table[frames[[-1]], 15], Reverse[frames]] ]
Licensing edit
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. | |
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 10:07, 3 June 2021 | 360 × 359 (5.78 MB) | Berto (talk | contribs) | Uploaded own work with UploadWizard |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
Metadata
This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.
GIF file comment | Created with the Wolfram Language : www.wolfram.com |
---|