File:Einwohnerentwicklung von Plauen.svg
Original file (SVG file, nominally 800 × 400 pixels, file size: 72 KB)
Captions
Summary edit
DescriptionEinwohnerentwicklung von Plauen.svg |
Deutsch: Einwohnerentwicklung von Plauen |
Source | Own work |
Author | Summer ... hier! (talk) 13:53, 12 March 2018 (UTC) |
Licensing edit
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. | |
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
Gnuplot script to generate this plot edit
#!/usr/bin/gnuplot
# gnuplot
# Variablen - die wichtigsten Paramter dieser Grafik:
# (in der Regel wird es reichen für eine neue Grafik diese Werte zu ändern)
my_data = 'Einwohnerentwicklung_von_Plauen.dat'
my_xrange_min = '01.01.1458'
my_xrange_max = '31.12.2017'
my_xtics_years = '100'
my_mxtics = '5'
my_yrange_min = '0'
my_yrange_max = '*' # Nur hier ist '*' erlaubt und sinnvoll
my_ytics = '25000'
my_ymtics = '5'
# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y" # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator
set datafile commentschars "#" # Kommentarzeichen
stats my_data u (strptime("%d.%m.%Y",strcol(1))) nooutput
my_diff = (STATS_max - STATS_min) / (60*60*24*365.25)
print ' -----Stats-(Timestamp)----'
print ' Start: ', STATS_min
print ' Ende: ', STATS_max
print ' Diff in Jahren: ', my_diff
print ' --------------------------'
# Anmerk.: die ausgegebenen Timestamps können in einer Shell bequem mit
# 'date -d @[Wert]' in humanleseriches Format gewandelt werden
# Allgemeines zur Ausgabe
set key vertical maxrows 6 # Max Anzahl Zeilen
set key left top # Legende links oben
set key opaque # ohne Transparenz
set key samplen 2 # Breite der Linenbeispiele
unset key # direkt vorher gesetzte Werte aufgehoben; ggf auskommentieren!
set style data lines # wird bei 'plot' überschrieben
set style fill transparent solid 0.4 # wird ebenfalls bei 'plot' überschrieben
set border 3 # Rahmen unten (Bit 1) und links (+ Bit 2)
set grid # Gitterlinien verwenden
# Gitterlinienen per Hand setzen falls gewünscht
set style line 1 linetype rgb '#696969' linewidth 0.5 dashtype 0 # Def. Major-grid
set style line 2 linetype rgb '#C9C9C9' linewidth 0.5 dashtype 3 # def. Minor-grid
set grid xtics mxtics # eventuell noxtics und nomxtics
set grid ytics mytics # eventuell noytics und nomytics
set grid back # Gitter im Hintergrund
set grid linestyle 1, linestyle 2 # Setzen des linestyle für Major u. Minor
#show grid # Kontrollausgabe auf der Konsole
# Farben - nummerische Equavalente zu Namen nach:
# https://www2.uni-hamburg.de/Wiss/FB/15/Sustainability/schneider/gnuplot/colors.htm
# Die beiden Ziffen am Ende der Variablen geben opacity/transparenz an
#
my_darkred_00 = '#008B0000'; my_darkred_20 = '#208B0000';
my_darkred_40 = '#408B0000'; my_darkred_60 = '#608B0000';
my_darkred_80 = '#808B0000'; my_darkred_a0 = '#a08B0000';
my_darkred_c0 = '#c08B0000'; my_darkred_e0 = '#e08B0000';
#
my_darkgreen_00 = '#00006400'; my_darkgreen_20 = '#20006400';
my_darkgreen_40 = '#40006400'; my_darkgreen_60 = '#60006400';
my_darkgreen_80 = '#80006400'; my_darkgreen_a0 = '#a0006400';
my_darkgreen_c0 = '#c0006400'; my_darkgreen_e0 = '#e0006400';
#
my_darkblue_00 = '#0000008B'; my_darkblue_20 = '#2000008B';
my_darkblue_40 = '#4000008B'; my_darkblue_60 = '#6000008B';
my_darkblue_80 = '#8000008B'; my_darkblue_a0 = '#a000008B';
my_darkblue_c0 = '#c000008B'; my_darkblue_e0 = '#e000008B';
#
my_darkmagenta_00 = '#008B008B'; my_darkmagenta_20 = '#208B008B';
my_darkmagenta_40 = '#408B008B'; my_darkmagenta_60 = '#608B008B';
my_darkmagenta_80 = '#808B008B'; my_darkmagenta_a0 = '#a08B008B';
my_darkmagenta_c0 = '#c08B008B'; my_darkmagenta_e0 = '#e08B008B';
#
my_darkorange_00 = '#00FF8C00'; my_darkorange_20 = '#20FF8C00';
my_darkorange_40 = '#40FF8C00'; my_darkorange_60 = '#60FF8C00';
my_darkorange_80 = '#80FF8C00'; my_darkorange_a0 = '#a0FF8C00';
my_darkorange_c0 = '#c0FF8C00'; my_darkorange_e0 = '#e0FF8C00';
#
my_darkturquoise_00 = '#0000CED1'; my_darkturquoise_20 = '#2000CED1';
my_darkturquoise_40 = '#4000CED1'; my_darkturquoise_60 = '#6000CED1';
my_darkturquoise_80 = '#8000CED1'; my_darkturquoise_a0 = '#a000CED1';
my_darkturquoise_c0 = '#c000CED1'; my_darkturquoise_e0 = '#e000CED1';
#
my_black_00 = '#00000000'; my_black_20 = '#20000000';
my_black_40 = '#40000000'; my_black_60 = '#60000000';
my_black_80 = '#80000000'; my_black_a0 = '#a0000000';
my_black_c0 = '#c0000000'; my_black_e0 = '#e0000000';
# Bereiche/Format/etc X-Achse
set xdata time # X-Achse als Zeitachse
set xlabel 'Jahr' # Beschriftung X-Achse
set xlabel offset 0, 0.75 # Schrift etwas höher
set xrange [ my_xrange_min : my_xrange_max]
# Wertebreich der X-Achse
set xtics '01.01.1000', (60*60*24*365.25) * my_xtics_years
# xtics in Sekunden
# der Beginn (Wert vor dem Komma) der X-Einteilung
# kann außerhalb xrange liegen
set xtics offset 0, 0.5 # Beschriftung näher an die X-Achse
set mxtics my_mxtics # Skalenstriche
set xtics nomirror # Nur unten Skalieren
set format x '%3Y' # Beschr.format JJJJ (bei 3 Stellen o. führend 0)
set xtics out # Skal. aussen damit sie nicht von Grafik
# überschr. wird
# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl' offset 2 # Abstand Achse/Label
# Untere Begrenzung des Bereichs der Y-Achse
set yrange [ my_yrange_min : ]
# Obere Begrenzung des Bereichs der Y-Achse
# wir Testen ob der Wert der Var. my_yrange_max ein '*' ist und reagieren
# entsprechend weil der '*' sich nicht direkt via Var. setzen lässt.
if ( ( my_yrange_max eq '*' )) set yrange [ : * ]
if (!( my_yrange_max eq '*' )) set yrange [ : my_yrange_max ]
set ytics my_ytics # Anzahl der kleinen Teilstriche
set ytics offset 0.5 # Schrift etwas nach rechts
set ytics nomirror # oben keine Teilstriche
set decimalsign locale "de_DE.utf8" # Stelle Input und Output auf "," um
# set decimalsign ',' würde nur Output umstellen,
set format y "%'.0f" # Ausgabeformat
set mytics my_ymtics # Unterskalierung
set ytics out # Skal. aussen da sie sonst von Grafik
# überschr. wird
#### Markierungsbalken für die beiden Weltkriege etc.
# Die set-Befehle ggf. auskommentieren
# Attribute für Markierungsbalken
set style rect fillcolor lt -1 fillstyle solid 0.1 noborder
#
# == Dreißigjähriger Krieg
set obj rect from '23.05.1618', graph 0 to '24.10.1648' , graph 1 back
set label "Dreißigjähriger Krieg" at '30.06.1633', graph 0.8 rotate by +60 center front
# == Siebenjähriger Krieg
# set obj rect from '29.08.1756', graph 0 to '21.09.1762' , graph 1 back
# set label "Siebenjähriger Krieg" at '30.06.1759', graph 0.8 rotate by +60 center front
# == Hamburger Franzosenzeit
# set obj rect from '30.06.1806', graph 0 to '30.06.1814' , graph 1
# set label "H. Franzosenzeit" at '01.01.1810', graph 0.3 rotate by +60 center
# == Befreiungskriege
#set obj rect from '26.02.1813', graph 0 to '20.11.1815' , graph 1 back
#set label "Befreiungskriege" at '30.06.1814', graph 0.8 rotate by +60 center front
# == 1. Weltkrieg
set obj rect from '28.07.1914', graph 0 to '11.11.1918' , graph 1 front
set label "1. Weltkrieg" at '30.06.1916', graph 0.3 rotate by +60 center front
# == 2. Weltkrieg
set obj rect from '01.09.1939', graph 0 to '04.05.1945' , graph 1 front
set label "2. Weltkrieg" at '30.06.1942', graph 0.9 rotate by +60 center front
# == Dädärä
set obj rect from '07.10.1949', graph 0 to '03.10.1990' , graph 1 back
set label "DDR" at '01.01.1970', graph 0.9 rotate by +60 center front
#
# == Markierung für Großstadtgrenze
# Mit Ein-/Auskommentieren festlegen ob bei 100.000 eine vertikale Linie gezogen werden soll
set arrow from my_xrange_min, '100000' to my_xrange_max, '100000' nohead lc rgb '#B0FF0000' back
# == Markierung für Millionenstadtgrenze
# Mit Ein-/Auskommentieren festlegen ob bei 100.000 eine vertikale Linie gezogen werden soll
set arrow from my_xrange_min, '1000000' to my_xrange_max, '1000000' nohead lc rgb '#B0FF0000' back
# Außenränder (keine Angabe entspricht Automatik)
set bmargin
set lmargin
set rmargin 1.5 # rechts entspr. der Wert bei Auto etwa 2.8
set tmargin
# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir bei UNIX in eine Pipe und sind so beim Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
# Windowsbenutzer, die mit Pipes nicht umgehen könnten, sollten das Kommentar-
# zeichen vor dem 'set output ...' folgenden Befehl entfernen.
# set output 'Einwohnerentwicklung_von_Plauen.svg'
set term svg size 800,400 font "Arial,16"
# Die Parameter von 'set term' sind so gewählt, das man in Wikipedia bei einer
# Einbindung [[Datei:Einwohnerentwicklung_von_Plauen.svg|mini|400px|Text]] noch Schrift/Details
# erkennen kann.
# Abkürzungen hinter dem Plot-Befehl:
# u : using
# w : with
# lc : linecolor
# lt : linetype
# lw : linewidth
# pt : pointtype
# ps : pointsize
# lp : linespoints
# p : points
# t : title
# not : notitle
# filledc : filledcurves (Bsp.: File:Einwohnerentwicklung von Wanne-Eickel.svg)
# rgb : RedGreenBlue
# Daten per Here-Document
# (siehe Abschntt 'Inline data and datablocks' in
# http://www.gnuplot.info/docs_5.2/Gnuplot_5.2.pdf )
#
$my_HD_1 << EndOfData_1
# bei 'plot' mit '$my_HD_1 use 1:2 with ...' einbinden
...
EndOfData_1
# Jede Kurve wird zweimal gezeichnet. Beim ersten mal mit etwas Transparenz
# damit es heller wird. Beim zweiten mal werden die Punkt dunkel
# nachgezeichnet. Dadurch sollte der Betrachter besser erkennen können, wo
# Messpunkte fehlen.
#
# Erzeugen der Ausgabe
plot \
my_data u 1:2 w lp lc rgb my_darkblue_40 lt 1 lw 1.5 pt 7 ps 0.22 t 'Einw. Entw.',\
my_data u 1:2 w p lc rgb my_darkblue_00 lt 1 lw 1.5 pt 7 ps 0.22 not ,\
# $my_HD_1 u 1:2 w lp lc rgb my_darkred_40 lt 1 lw 1.5 pt 7 ps 0.22 t 'Einw. Entw.',\
# $my_HD_1 u 1:2 w p lc rgb my_darkred_00 lt 1 lw 1.5 pt 7 ps 0.22 not ,\
Daten edit
Die folgenden Daten bitte in eine Textdatei unter dem Namen "Einwohnerentwicklung_von_Plauen.dat" abspeichern und ins gleiche Verzeichnis wie das GnuPlot-Script ablegen.
Update der Daten und Überschreiben der Grafik ausdrücklich erwünscht (bei Problemen beim Erstellen einer neuen Grafik unter de:Benutzer Diskussion:Summer ... hier! oder de:Wikipedia:Grafikwerkstatt nachfragen).
Vor Änderungen der Struktur dieses Abschnitts bitte beachten, das die Daten zur Wartung anderer Grafiken benutzt werden. Dies sind Dateien, die möglicherweise die Daten dieses Abschnitts verwenden.
#
# Quelle:
# https://de.wikipedia.org/wiki/Einwohnerentwicklung_von_Plauen#Einwohnerentwicklung
#
30.06.1458 ; 1500
30.06.1602 ; 3500
30.06.1633 ; 1500
30.06.1801 ; 5709
30.06.1831 ; 8500
01.12.1834 ; 9029
01.12.1840 ; 10152
03.12.1849 ; 12334
03.12.1855 ; 13812
03.12.1858 ; 14817
03.12.1861 ; 16200
#
03.12.1864 ; 18600
03.12.1867 ; 20500
01.12.1871 ; 22844
01.12.1875 ; 28756
01.12.1880 ; 35082
01.12.1885 ; 42848
01.12.1890 ; 47007
02.12.1895 ; 55191
01.12.1900 ; 73891
01.12.1905 ; 105381
01.12.1910 ; 121272
#
31.12.1912 ; 128014
01.12.1916 ; 90065
05.12.1917 ; 87602
08.10.1919 ; 104918
31.12.1920 ; 108576
16.06.1925 ; 111398
31.12.1930 ; 114564
16.06.1933 ; 113855
31.12.1935 ; 112502
17.05.1939 ; 111891
31.12.1940 ; 112200
#
#
#
01.12.1945 ; 82134
29.10.1946 ; 84778
31.08.1950 ; 84438
31.12.1950 ; 84485
31.12.1951 ; 84645
31.12.1952 ; 83048
31.12.1953 ; 82165
31.12.1954 ; 82041
31.12.1955 ; 81998
31.12.1956 ; 81105
31.12.1957 ; 80125
31.12.1958 ; 79794
31.12.1959 ; 79743
31.12.1960 ; 79056
31.12.1961 ; 78905
#
31.12.1962 ; 78983
31.12.1963 ; 79111
31.12.1964 ; 81250
31.12.1965 ; 81739
31.12.1966 ; 82053
31.12.1967 ; 82046
31.12.1968 ; 82008
31.12.1969 ; 81951
31.12.1970 ; 82026
31.12.1971 ; 81712
31.12.1972 ; 81279
31.12.1973 ; 80871
31.12.1974 ; 80353
31.12.1975 ; 79899
31.12.1976 ; 79581
#
31.12.1977 ; 79500
31.12.1978 ; 79190
31.12.1979 ; 78882
31.12.1980 ; 78828
31.12.1981 ; 79071
31.12.1982 ; 78647
31.12.1983 ; 78797
31.12.1984 ; 77913
31.12.1985 ; 77570
31.12.1986 ; 77514
31.12.1987 ; 77116
31.12.1988 ; 77593
31.12.1989 ; 73971
#
#
#
31.12.1990 ; 71774
31.12.1991 ; 70856
31.12.1992 ; 70284
31.12.1993 ; 69387
31.12.1994 ; 68308
31.12.1995 ; 68033
31.12.1996 ; 67378
31.12.1997 ; 66497
31.12.1998 ; 66305
31.12.1999 ; 71955
#
31.12.2000 ; 71543
31.12.2001 ; 71155
31.12.2002 ; 70534
31.12.2003 ; 70070
31.12.2004 ; 69422
31.12.2005 ; 68892
31.12.2006 ; 68430
31.12.2007 ; 67600
31.12.2008 ; 66870
31.12.2009 ; 66287
#
31.12.2010 ; 66098
31.12.2011 ; 65738
31.12.2012 ; 64115
31.12.2013 ; 63967
31.12.2014 ; 64077
31.12.2015 ; 65201
31.12.2016 ; 65049
31.12.2017 ; 65148
# EOF
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 11:30, 16 November 2018 | 800 × 400 (72 KB) | Summer ... hier! (talk | contribs) | +Wert 2017 | |
17:38, 14 April 2018 | 800 × 400 (92 KB) | Summer ... hier! (talk | contribs) | +Marker bei Grenze zur Großstadt | ||
13:53, 12 March 2018 | 800 × 400 (91 KB) | Summer ... hier! (talk | contribs) | {{Information |Description = {{de|Einwohnerentwicklung von Plauen}} |Source = {{own}} |Author = ~~~~ |Date = }} == {{int:license-header}} == {{self|Cc-zero}} == Gnuplot script to generate this plot == {{gnuplot}}{{ValidSVG}}<!--{{Created with Gnuplot | v }}--> <source lang="gnuplot"> #!/usr/bin/gnuplot # gnuplot # Variablen - die wichtigsten Paramter dieser Grafik: # (in der Regel wird es reichen für eine neue Grafik diese Werte zu ändern) my_data = 'Einwohnerentwicklung_von_Plauen.dat' my_xrange_min = '30.06.1458' my_xrange_max = '31.12.2016' my_xtics_years = '50' my_mxtics = '5' my_yrange_min = '0' my_yrange_max = '*' # Nur hier ist '*' erlaubt und sinnvoll my_ytics = '25000' my_ymtics = '5' # Allgemeines zu den Eingabedaten set timefmt "%d.%m.%Y" # Zeitangaben in TT.MM.YYYY set datafile separator ";" # Spaltenseparator # Allgemeines zur Ausgabe... |
You cannot overwrite this file.
File usage on Commons
The following 2 pages use this file:
File usage on other wikis
The following other wikis use this file:
- Usage on de.wikipedia.org
- Usage on pl.wikipedia.org
Metadata
This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.
Short title | Gnuplot |
---|---|
Image title | Produced by GNUPLOT 5.0 patchlevel 3 |
Width | 800 |
Height | 400 |