#!/usr/bin/gnuplot
# gnuplot 


# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"     # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator 


# Allgemeines zur Ausgabe
unset key
set style data lines
set style fill transparent solid 0.4
set grid
set border 3               # Bit 1 (unten) + Bit 2 (links)


# Bereiche/Format/etc X-Achse 
set xdata time
set xlabel 'Jahr'          # Beschr. X-Achse
set xlabel offset 0, 0.75  # Schrift etwas höher
set xrange ['30.06.1593':'30.06.2014']
set xtics '01.01.1000', 60 * 60 * 24 * 365.25 * 50
                           # xtics in Sekunden 
                           # der Beginn der X-Einteilung kann außerhalb xrange
                           # liegen
set xtics offset  0, 0.5   # Beschritung näher an die X-Achse
set mxtics 5               # Skalenstriche 
set xtics nomirror         # Nur unten Skalieren
set format x '%Y'          # Beschriftungsformat JJJJ
set xtics  out             # Skal. aussen damit sich nicht von Grafik 
                           # überschr. wird


# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl' offset 2 # Abstand Achse/Label 
set yrange [0:]
set ytics 2500
set ytics offset 0.5       # Schrift etwas nach rechts
set ytics nomirror
set decimalsign locale "de_DE.utf8"
set decimal     locale "de_DE.utf8"
set format y  "%'.0f"      # Ausgabeformat
set mytics 5
set ytics  out             # Skal. aussen da sie sonst von Grafik 
                           # überschr. wird


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
set term svg size 800,400 font "Arial,14"
# keine "set output '<Dateiname>'" Angabe


# Erzeugen der Ausgabe 
plot \
  'Einwohnerentwicklung_von_Sarstedt.dat' using 1:2 with linespoints linecolor 'dark-blue'   linetype 1 linewidth 1.5 pointtype 7 pointsize 0.30