File:Light scattering - Averaging.gif
Light_scattering_-_Averaging.gif (600 × 299 pixels, file size: 4.51 MB, MIME type: image/gif, looped, 60 frames, 12 s)
Captions
Captions
Summary
editDescriptionLight scattering - Averaging.gif |
English: Coherent light incident on a scattering medium will produce a volume speckle inside the material. But if you start averaging over more and more realizations of the disorder, the average doesn't look like speckle anymore.
The real part of the electric field (right panel) inside the scattering medium averages to zero, but not immediately. There is a region inside where the amplitude decays exponentially, showing that not all the light is scattered immediately (Lamber-Beer law). The intensity of the electric field (left panel) can not average to zero, as it is a positive quantity, but it gets smoother and smoother. To a good approximation the average light intensity in a scattering medium can actually be described using the diffusion equation! |
Date | |
Source | https://twitter.com/j_bertolotti/status/1413159977854849029 |
Author | Jacopo Bertolotti |
Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 12.0 code
edit\[Lambda]0 = 1.; k0 =
N[(2 \[Pi])/\[Lambda]0]; (*The wavelength in vacuum is set to 1, so all lengths are now in units of wavelengths*)
\[Delta] = \[Lambda]0/10; \[CapitalDelta] = 50*\[Lambda]0; (*Parameters for the grid*)
ReMapC[x_] := RGBColor[(2 x - 1) UnitStep[x - 0.5], 0, (1 - 2 x) UnitStep[0.5 - x]];
\[Sigma] = 10 \[Lambda]0;
d = \[Lambda]0/2; (*typical scale of the absorbing layer*)
imn = Table[
Chop[5 (E^-((x + \[CapitalDelta]/2)/d) + E^((x - \[CapitalDelta]/2)/d) + E^-((y + \[CapitalDelta]/2)/d) + E^((y - \[CapitalDelta]/2)/d))], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}]; (*Imaginary part of the refractive index (used to emulate absorbing boundaries)*)
dim = Dimensions[imn][[1]];
L = -1/\[Delta]^2*KirchhoffMatrix[GridGraph[{dim, dim}]]; (*Discretized Laplacian*)
optimizedpoint = Round[0.7 dim];
sourcelist = Table[x0, {x0, -\[CapitalDelta]/2 + 2, \[CapitalDelta]/2 - 2, 1}];
sourcedim = Dimensions[sourcelist][[1]];
ren0 = 2;
\[Phi] = Table[
ren = ren0*Clip[Total[Table[RotateRight[DiskMatrix[5, dim], {RandomInteger[{-Round[dim/2], Round[dim/2] }], RandomInteger[{ -Round[dim/8], Round[dim/2] - 10}]}], {200}]], {0, 1}] + 1;
n = ren + I imn;
phases = Table[
\[Phi]in = Table[E^(-((x - sourcelist[[j]])^2/(2 (\[Lambda]0/2)^2))) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))), {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];(*Discretized source*)
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
\[Phi] = Partition[LinearSolve[M, b], dim]; (*Solve the linear system*)
Arg[\[Phi][[Round[dim/2] , optimizedpoint ]] ]
, {j, 1, sourcedim, 1}];
\[Phi]in = Total@Table[Table[E^(-((x - sourcelist[[j]])^2/(2 (\[Lambda]0/2)^2))) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) E^(-I phases[[j]]), {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}], {j, 1, sourcedim}];(*Discretized source*)
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
Partition[LinearSolve[M, b], dim] (*Solve the linear system*)
, {50}];
\[Phi]0 = Table[ren =
ren0*Clip[Total[Table[RotateRight[DiskMatrix[5, dim], {RandomInteger[{-Round[dim/2], Round[dim/2] }], RandomInteger[{ -Round[dim/8], Round[dim/2] - 10}]}], {250}]], {0, 1}] + 1;
n = ren + I imn;
\[Phi]in = Total@Table[Table[E^(-((x - sourcelist[[j]])^2/(2 (\[Lambda]0/2)^2))) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) , {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}], {j, 1, sourcedim}];(*Discretized source*)
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
Partition[LinearSolve[M, b], dim] (*Solve the linear system*)
, {50}];
frames = Table[GraphicsRow[{
ArrayPlot[
Transpose[(Mean[Abs[#]^2 & /@ \[Phi]0[[1 ;; j]] ]/Max[avg\[Phi]0abs[[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]])][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]], ColorFunction -> "AvocadoColors", DataReversed -> True, Frame -> False, PlotRange -> {0, 1}, LabelStyle -> {Black, Bold}, ColorFunctionScaling -> False],
ArrayPlot[
Transpose[(Mean[Re[#] & /@ \[Phi]0[[1 ;; j]] ]/Sqrt[Max[avg\[Phi]0abs[[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]]])][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]], ColorFunction -> ReMapC, DataReversed -> True, Frame -> False, PlotRange -> {-1, 1}, LabelStyle -> {Black, Bold}, ColorFunctionScaling -> True]
}]
, {j, 1, 50}];
ListAnimate[frames]
Licensing
edit![]() ![]() |
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 10:19, 9 July 2021 | ![]() | 600 × 299 (4.51 MB) | Berto (talk | contribs) | Uploaded own work with UploadWizard |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
Metadata
This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.
GIF file comment | Created with the Wolfram Language : www.wolfram.com |
---|