Equations:

1. t ∈ [0 ; T/8] ${\displaystyle {\begin{cases}x={\frac {2}{\pi +2}}x_{\mathrm {f} }\left[{\frac {t}{\mathrm {T} }}-{\frac {1}{4\pi }}\sin \left(4\pi {\frac {t}{\mathrm {T} }}\right)\right]\\v={\frac {2}{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} }}\left[1-\cos \left(4\pi {\frac {t}{\mathrm {T} }}\right)\right]\\a={\frac {8\pi }{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{2}}}\sin \left(4\pi {\frac {t}{\mathrm {T} }}\right)\\j={\frac {32\pi ^{2}}{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{3}}}\cos \left(4\pi {\frac {t}{\mathrm {T} }}\right)\end{cases}}}$

2. t ∈ [T/8 ; 3T/8] ${\displaystyle {\begin{cases}x={\frac {4\pi }{\pi +2}}x_{\mathrm {f} }\left[{\frac {t^{2}}{\mathrm {T} ^{2}}}+{\frac {2-\pi }{4\pi }}{\frac {t}{\mathrm {T} }}+{\frac {\pi ^{2}-8}{64\pi ^{2}}}\right]\\v={\frac {8\pi }{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} }}\left[{\frac {t}{\mathrm {T} }}+{\frac {2-\pi }{8\pi }}\right]\\a={\frac {8\pi }{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{2}}}\\j=0\end{cases}}}$

3. t ∈ [3T/8 ; 5T/8] ${\displaystyle {\begin{cases}x={\frac {2}{\pi +2}}x_{\mathrm {f} }\left[(1+\pi ){\frac {t}{\mathrm {T} }}-{\frac {1}{4\pi }}\cos \left(4\pi \left({\frac {t}{\mathrm {T} }}-{\frac {3}{8}}\right)\right)-{\frac {\pi }{4}}\right]\\v={\frac {2}{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} }}\left[1+\pi +\sin \left(4\pi \left({\frac {t}{\mathrm {T} }}-{\frac {3}{8}}\right)\right)\right]\\a={\frac {8\pi }{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{2}}}\cos \left(4\pi \left({\frac {t}{\mathrm {T} }}-{\frac {3}{8}}\right)\right)\\j=-{\frac {32\pi ^{2}}{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{3}}}\sin \left(4\pi \left({\frac {t}{\mathrm {T} }}-{\frac {3}{8}}\right)\right)\end{cases}}}$

4. t ∈ [5T/8 ; 7T/8] ${\displaystyle {\begin{cases}x={\frac {4\pi }{\pi +2}}x_{\mathrm {f} }\left[-{\frac {t^{2}}{\mathrm {T} ^{2}}}+{\frac {2+7\pi }{4\pi }}{\frac {t}{\mathrm {T} }}-{\frac {33\pi ^{2}-8}{64\pi ^{2}}}\right]\\v={\frac {8\pi }{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} }}\left[-{\frac {t}{\mathrm {T} }}+{\frac {7\pi +2}{8\pi }}\right]\\a=-{\frac {8\pi }{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{2}}}\\j=0\end{cases}}}$

5. t ∈ [7T/8 ; T] ${\displaystyle {\begin{cases}x={\frac {2}{\pi +2}}x_{\mathrm {f} }\left[{\frac {t}{\mathrm {T} }}-{\frac {1}{4\pi }}\sin \left(4\pi \left({\frac {t}{\mathrm {T} }}-1\right)\right)+{\frac {\pi }{2}}\right]\\v={\frac {2}{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} }}\left[1-\cos \left(4\pi \left({\frac {t}{\mathrm {T} }}-1\right)\right)\right]\\a={\frac {8\pi }{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{2}}}\sin \left(4\pi \left({\frac {t}{\mathrm {T} }}-1\right)\right)\\j={\frac {32\pi ^{2}}{\pi +2}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{3}}}\cos \left(4\pi \left({\frac {t}{\mathrm {T} }}-1\right)\right)\end{cases}}}$

This media was created with Scilab, a free open-source software. Here is a listing of the Scilab source used to create this file.

function [t1, t2, t3, t4, t5] = indice(t)
    t1 = (t <= 1/8);
    t2 = (t > 1/8) & (t <= 3/8);
    t3 = (t>3/8) & (t<=5/8);
    t4 = (t>5/8) & (t<=7/8);
    t5 = (t>7/8);
endfunction

function [j]=jerk(t)
    [t1, t2, t3, t4, t5] = indice(t)
    j = zeros(t);
    j0 = 32*%pi^2/(%pi + 2)
    j(t1) = j0*cos(4*%pi*t(t1));
    j(t2) = 0;
    j(t3) = -j0*sin(4*%pi*(t(t3) - 3/8));
    j(t4) = 0;
    j(t5) = j0*cos(4*%pi*(t(t5) - 1));
endfunction

function [a]=acceleration(t)
    [t1, t2, t3, t4, t5] = indice(t)
    a = zeros(t);
    a0 = 8*%pi/(%pi + 2);
    a(t1) = a0*sin(4*%pi*t(t1));
    a(t2) = a0;
    a(t3) = a0*cos(4*%pi*(t(t3) - 3/8));
    a(t4) = -a0;
    a(t5) = a0*sin(4*%pi*(t(t5) - 1));
endfunction

function [v] = vitesse(t)
    [t1, t2, t3, t4, t5] = indice(t)
    v = zeros(t);
    v0 = 2/(%pi + 2);
    v(t1) = v0*(1 - cos(4*%pi*t(t1)));
    v(t2) = v0*4*%pi*(t(t2) + (2 - %pi)/(8*%pi));
    v(t3) = v0*(sin(4*%pi*(t(t3) - 3/8)) + %pi + 1);
    v(t4) = v0*4*%pi*(-t(t4) + (7*%pi + 2)/(8*%pi));
    v(t5) = v0*(1 - cos(4*%pi*(t(t5) - 1)));
endfunction

function [x] = position(t)
    [t1, t2, t3, t4, t5] = indice(t)
    x = zeros(t);
    x0 = 2/(%pi + 2);
    x(t1) = x0*(t(t1) - 1/(4*%pi)*sin(4*%pi*t(t1)));
    x(t2) = x0*2*%pi*((t(t2) + (2-%pi)/(4*%pi)).*t(t2) + (%pi^2-8)/(64*%pi^2));
//    x(t3) = x0*((%pi + 1)*t(t3) - 1/(4*%pi)*cos(4*%pi*(t(t3) - 3/8))...
//       + (%pi^3 - 9*%pi^2 - 8*%pi + 8)/(32*%pi));
    x(t3) = x0*((1 + %pi)*t(t3) - 1/(4*%pi)*cos(4*%pi*(t(t3) - 3/8)) - %pi/4);
    x(t4) = x0*2*%pi*((-t(t4) + (7*%pi + 2)/(4*%pi)).*t(t4) +...
       (- 33*%pi^2 + 8)/(64*%pi^2));
    x(t5) = x0*(t(t5) - 1/(4*%pi)*sin(4*%pi*(t(t5) - 1)) + %pi/2);
endfunction

// tracé

t = 0:0.005:1;

j = jerk(t);
a = acceleration(t);
v = vitesse(t);
x = position(t);

scf(0);
clf;

subplot(4, 1, 1)
plot(t, x)
xtitle("position", "t/T", "$x/x_\mathrm{f}$")

subplot(4, 1, 2)
plot(t, v)
xtitle("vitesse", "t/T", "$v/(x_\mathrm{f}/\mathrm{T})$")

subplot(4, 1, 3)
plot(t, a)
xtitle("accélération", "t/T", "$a/(x_\mathrm{f}/\mathrm{T}^2)$")

subplot(4, 1, 4)
plot(t, j)
xtitle("à-coup", "t/T", "$j/(x_\mathrm{f}/\mathrm{T}^3)$")

I, the copyright holder of this work, hereby publish it under the following license:

This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.

You are free:

• to share – to copy, distribute and transmit the work
• to remix – to adapt the work

Under the following conditions:

• attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
• share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue