Summary edit

Script in POVray edit

// Schnitt durch ein PhotoelectronSpetroskopie Experiment
// by Matthias Kreier
#version 0.8;
global_settings { assumed_gamma 1.0 }
#default{ finish{ ambient 0.6 diffuse 0.4 }}

#include "colors.inc"  
#include "textures.inc"         

camera {
    ultra_wide_angle
    angle 48
    location <20, 30, -65>
    look_at <-2, 12, 0>
}               

//plane { <0, 1, 0>, -1 pigment { color Red } }
//plane { <0, 0, -1>, -50 pigment { color White} }
plane { <0, 1, -1>, -2000 pigment { color LightGray} }

//  ****** Linsensystem zur Fokussierung und Retardierung *******

#declare Linsensystem =
union{ 
 difference{
  union{
    box{<-2.1,3.0,-2.1>,<2.1,3.2,2.1>}
    box{<-2.1,3.4,-2.1>,<2.1,3.6,2.1>}
    box{<-2.1,3.8,-2.1>,<2.1,4.0,2.1>}
    box{<-2.1,6.8,-2.1>,<2.1,7.0,2.1>} 
    pigment { color Blue }   
  }
  cylinder { < 0,2.9,0 > <0,7.1,0> 0.81 pigment { color Silver } }
  cylinder { < 0,2.9,0 > <0,7.1,0> 2 pigment { color Silver } inverse }
 }
 difference{
  union{
    cylinder{ < 0,4.2,0 > <0,4.4,0> 2.1 }
    cylinder{ < 0,4.3,0 > <0,6.5,0> 1.4 }
    cylinder{ < 0,6.4,0 > <0,6.6,0> 2.1 }
    cylinder{ < 0,7.2,0 > <0,7.4,0> 2.1 }
    cylinder{ < 0,7.3,0 > <0,9.9,0> 1.4 }
    cylinder{ < 0,9.8,0 > <0,10,0> 2.1 }
    cylinder{ < 0,10.2,0 > <0,10.4,0> 2.1 }
    cylinder{ < 0,10.3,0 > <0,11.2,0> 1.4 } 
  }
  cylinder { < 0,4.1,0 > <0,11,0> 1.2 pigment { color Silver } }
  cylinder { < 0,10.9,0 > <0,11.3,0> 0.8 pigment { color Silver } }
  cylinder { < 0,4.1,0 > <0,11.3,0> 2 pigment { color Silver } inverse }
 } 
 translate <0,1,0>
}

#declare Kugelanalysator =
union{
 intersection{  // innere Kugel
  difference{
   sphere{<6,14,0>,4.2 texture{Polished_Chrome} }
   sphere{<6,14,0>,4 pigment{color Blue} }
  }
  box{<1,14,-1>,<11,19,5> pigment{color Red}}  
 }
 intersection{  // äußere Kugel
  difference{
   sphere{<6,14,0>,8 pigment{color Blue} }
   sphere{<6,14,0>,7.8 pigment{color Silver} }
  }
  box{<-3,14,-1>,<15,23,9> pigment{color Red}}  
 }
 difference{  // Herzog-Platte 
  cylinder { < 6,12.5,0 > < 6,13,0 > 9 pigment { color LightSteelBlue } }
  cylinder { < 0,12.4,0>,<0,13.1,0>  1.1 pigment{color Silver}}
  cylinder { < 12,12.4,0>,<12,13.1,0>  2.3 }
 } 
 difference{ 
  cylinder { < 12,12.5,0 > < 12,13.8,0 > 2.4 pigment { color Blue } }
  cylinder { < 12,12.4,0> < 12,13.9,0>  2.2 pigment{color Silver}}  
 }  
 intersection{ // Eingangsspalte
  union{
   box {<-2,13.25,-2>,<2,13.35,2> pigment{color Blue} }
   box {<-0.6,13.3,-2>,<0.6,13.75,2> pigment{color Blue} }
  }
  box {<-0.2,13.2,-2.1>,<0.2,14.1,2.1> pigment{color Silver} inverse}
 }
 intersection{ // Eingangsblenden
  union{
   cylinder { < 0,13.85,0 > < 0,13.9,0 > 2 pigment{color Blue} }
   cylinder { < 0,13.1,0 > < 0,13.15,0 > 2 pigment{color Blue} }
  }
  box {<-0.15,13.0,-1>,<0.15,14.1,1> pigment{color Silver} inverse}
 }

}                 

#declare Optik =
union{
  object { Linsensystem
           pigment { color Blue }
         } 
  object { Kugelanalysator }
  rotate<0,0,0>
}
                
#declare Scienta =                
union{ 
 intersection{ // Linsensystem und Analysator entlang x aufgeschnitten  
  object { Optik }
  box{
      <-3,2,0>, <15,23,9> 
      pigment{color Red}
  }
 } 
 intersection{ //aufgeschnitten
  union{
   cylinder{<12,13.3,0> <12,13.8,0> 2 pigment{color CadetBlue}}  // Channelplate
   cylinder{<12,13.0,0> <12,13.2,0> 2 pigment{color Green}}  // Phosphorplatte
  }
  box{ <9,10,0>, <15,15,9> pigment{color rgbf <1,1,1,1>}}
 }
 difference{   // CCD Kamera
   cylinder{<12,9.5,0> <12,11,0> 1.8 pigment{color CadetBlue}}
   cylinder{<12,10 ,0> <12,11.1,0> 1.6 pigment{color Black}}
 }
 cylinder{<12,9.6,0> <12,8,0> 1.4 pigment{color CadetBlue}}
 cylinder{<12,8.1,0> <12,5.5,0> 1.8 pigment{color CadetBlue}}   
 cone{<12,11,0> 1.6 <12,13,0> 2 texture{pigment{rgbf<1,1,0.8,0.7>}}
}

// *************    Weg der Elektronen  *********
#declare Elektron1 =
union{
 cone { < 0,0,0 >, 0, <0,21.5,0>, 0.6 }
 cone { < 0,21.5,0 >, 0.6, <0,23,0>, 0.4 } 
 cone { < 0,23,0 >, 0.4, <0,24.2,0>,0.03} 
 cone { < 0,24,0 >, 0.03,<0,25,0>, 0.5 }
 cone { < 0,25,0 >, 0.5, <0,26,0>, 0.6 }
 cone { < 0,26,0 >, 0.6, <0,27,0>, 0.5 }
 cone { < 0,27,0 >, 0.5, <0,29.5>, 0.05 }
 cone { < 0,29.5,0>,0.05,<0,30,0>, 0.1 }
 intersection{
  intersection{
   torus{ 6,0.5 rotate<-3.8,0,0> translate <0,0.46,0> }
   torus{ 6,0.5 rotate< 3.8,0,0> translate <0,-0.46,0> }
   torus{ 6,0.7 translate <-0.67,0,0> }
   torus{ 6,0.7 translate < 0.67,0,0> }
   rotate<90,0,0>
   translate<6,30,0>    
  }                               
//  torus{ 6,0.1 rotate < 90,0,0 > translate<6,30,0> }                               
  box{<-2,30,-2>,<13,39,2>} 
 }
}

#declare Elektron2 =
union{
 intersection{
  intersection{
   torus{ 6,0.5 rotate<-3.8,0,0> translate <0,0.46,0> }
   torus{ 6,0.5 rotate< 3.8,0,0> translate <0,-0.46,0> }
   torus{ 6,0.7 translate <-0.67,0,0> }
   torus{ 6,0.7 translate < 0.67,0,0> }
   rotate<90,8,0>
   translate<6,14,0>    
  }                               
  box{<-2,14,-2>,<13,23,2>}
 }                      
 cone { < 0,11,0.9 >, 0.2, <0,14.1,0.9>, 0.05 }
 cylinder { < 0,5.95,0.9 > <0,11,0.9> 0.2 } 
 cone { < 0,0,0 >, 0, <0,6,0.9>, 0.2 }
}

#declare Elektron3 =
union{
 intersection{
  intersection{
   torus{ 6,0.5 rotate<-3.8,0,0> translate <0,0.46,0> }
   torus{ 6,0.5 rotate< 3.8,0,0> translate <0,-0.46,0> }
   torus{ 6,0.7 translate <-0.67,0,0> }
   torus{ 6,0.7 translate < 0.67,0,0> }
   rotate<90,-10,0>
   translate<6,14,0>    
  }                               
  box{<-2,14,-2>,<13,23,2>}
 }                      
 cone { < 0,11,-0.9 >, 0.2, <0,14.1,-0.9>, 0.05 }
 cylinder { < 0,4.95,-0.9 > <0,11,-0.9> 0.2 } 
 cone { < 0,0,0 >, 0, <0,5,-0.9>, 0.2 }
}

#declare Lichtquelle =
union{
 cylinder{ 
   <-18,18,0> <1,-1,0> 0.5 
   texture{pigment{rgbf<1,1,0.6,0.7>}}
 } 
 difference{
   cylinder{ <-17.5,17.5.0> <-40,40,0> 1.8 }
   cylinder{ <-17.4,17.4.0> <-20,20,0> 0.5 }
   pigment { color RichBlue }
 }
}

#declare Sample = 
union{
 box{<-14.8,-2.5,-14.8>,<14.8,0,14.8> pigment{color LightBlue}}
 union{ // Koordinatensystem
  cylinder{ < 0,0,0 > < 16.1,0,0 > 0.1 } 
  cylinder{ < 0,0,0 > < 0,16.1,0 > 0.1 } 
  cylinder{ < 0,0,0 > < 0,0,-16.1> 0.1 } 
  cone{ < 16,0,0 > 0.3 < 17,0,0 > 0 }
  cone{ < 0,16,0 > 0.3 < 0,17,0 > 0 }
  cone{ < 0,0,-16> 0.3 < 0,0,-17> 0 }
  intersection{
   torus{ 8,0.1 }
   box { < 0,-0.1,-8.1 > < 5.66,0.1,-5.66> }  
  }
  cylinder{ < 0,0,0 > < 6,0,-6 > 0.1 }
  intersection{
   torus{ 10,0.1 }
   box { < 0,-0.1,-10.1 > < 4.8,0.1,-4.8> }
   rotate <90,45,0>  
  }
  cone{ < 5.66,0,-5.66 > 0 < 5,0,-6.3 > 0.3 }
  cone{ < 3.38,8.8,-3.38> 0 < 2.5,9.3,-2.5> 0.3 }
  pigment{color Green}
 } 
 cylinder{ 
   < 5.66,15,-5.66> < 5.66,0,-5.66 > 0.1 
   pigment{checker color Green color rgbf <1,1,1,1>}}
 }
}

// **********  alles zusammenbauen *********

object { Scienta translate < 0,16,0 > rotate < -20,0,-20 > }

object{ Elektron1 pigment{color Orange} rotate < -20,0,-20 > }
//object{ Elektron2 pigment{color rgbf <1,0.6,0,0.8>} }
//object{ Elektron3 pigment{color rgbf <1,1,0,0.8>} }

object { Lichtquelle } 

object { Sample }
                         

// *********  Lichtquellen  ************

                         
                        
light_source {
    <-60, 28, -200>
    color White
}

light_source {
//    <0, 26, -20>
//    <30, 30, -45>
    <20, 30, -65>
    color White
} 

/*
light_source {      // Rückseite beleuchten
    <20, 30, 10>
    color White
}  */
/*
light_source {      // Kugel innen Licht
    <9, 21, 1.5>
    color White
} 
*/

Licensing edit

I, the copyright holder of this work, release this work into the public domain. This applies worldwide. In some countries this may not be legally possible; if so: I grant anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law.