Wikimedia Commons

File:Two polarizers animation.gif

Two_polarizers_animation.gif ‎(500 × 500 pixels, file size: 3.56 MB, MIME type: image/gif, looped, 101 frames, 10 s)

Captions

Captions

Perpendicularly rotated polarizers block all the incoming light

Summary edit

Description
English: From the incoming circularly polarized light only its vertical component propagates through the first polarizer. When another polarizer is inserted after the first one, the polarization and intensity of the outgoing light depend on the rotation angle of the second polarizer. When the second polarizer is set to 90 degrees, no light makes it through.
Čeština: Z kruhově polarizovaného světla je lineárním polarizátorem vyfiltrována vertikální polarizace. Další přidaný polarizátor tuto polarizaci již dále nezmění, je-li ve výchozí poloze. S natočením druhého polarizátoru je vyfiltrováno čím dál méně světla v závislosti na úhlu natočení. Pokud je úhel roven 90 stupňům, neprochází druhým polarizátorem již žádné světlo.
Date
Source Own work
Author JozumBjada

Licensing edit

I, the copyright holder of this work, hereby publish it under the following license:
w:en:Creative Commons
attribution share alike
This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.
You are free:
  • to share – to copy, distribute and transmit the work
  • to remix – to adapt the work
Under the following conditions:
  • attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
  • share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

Source code edit

This animation was created using Wolfram language 12.0.0 for Microsoft Windows (64-bit) (April 6, 2019). The source code follows. 

(* ::Package:: *)

(* ::Title:: *)
(*Two polarizers*)

(* ::Text:: *)
(*Version: "12.0.0 for Microsoft Windows (64-bit) (April 6, 2019)"*)

(* ::Section:: *)
(*Parameters*)

(* ::Input::Initialization:: *)
innerrad=0.8;
outerthick=.3;
innerthick=.2;
dist=2;

(* ::Input::Initialization:: *)
black=GrayLevel[0.3];

(* ::Input::Initialization:: *)
fontFamily="Times New Roman";
fontSize=25;

(* ::Input::Initialization:: *)
ang1=0.619;
ang2=0.772;
ang12=0.843;

(* ::Section:: *)
(*Polarizer*)

(* ::Input::Initialization:: *)
rim=ChartElementData["CylindricalSector3D"][{{0,2Pi},{innerrad,1},{-outerthick/2,outerthick/2}},1];
 (*courtesy: suggestion by user 'kglr' at: https://mathematica.stackexchange.com/questions/153536/thick-annulus-ring-in-3d*)

(* ::Input::Initialization:: *)
coating=DensityPlot[y ,{x,-1,1},{y,-1,1},RegionFunction->(#1^2+#2^2<=1&),ColorFunction->(ColorData["Rainbow"][Mod[2#1,1]]&),PlotStyle->Opacity[.5],Frame->False];
coating=First@Cases[InputForm[coating],_GraphicsComplex,Infinity];
coating=Rasterize[Graphics@coating,ImageResolution->50,Background->None];
coating={Texture[coating],EdgeForm[None],Polygon[{{-1,-1,0},{1,-1,0},{1,1,0},{-1,1,0}},VertexTextureCoordinates->{{0,0},{1,0},{1,1},{0,1}}]};

(* ::Input::Initialization:: *)
filter={EdgeForm[None],
{Opacity[.5],LightBlue,Cylinder[{{0,0,-innerthick/2},{0,0,innerthick/2}},innerrad-.001]},
{coating},
{Gray,rim,Scale[rim,{1.03,1.03,.6}]},
{Darker[black],Cuboid[{innerrad,-0.02,0},{1.01,0.02,1.3outerthick/2}],Cuboid[{-innerrad,-0.02,0},{-1.01,0.02,1.3outerthick/2}]}
};

(* ::Input::Initialization:: *)
arc[ang_]:=Module[{c=1,ampl=1.5,aux},
If[ang==0,Return[{}]];
aux=ParametricPlot3D[{ampl Cos[c t],ampl Sin[c t],0},{t,0,-ang}];
aux=First@Cases[InputForm[aux],_Line,Infinity];
If[ang>25Degree,Arrow[Tube[Reverse@First@aux,.02]],Tube[aux,.02]]
];

(* ::Input::Initialization:: *)
reticule[ang_]:=With[{len=1.8},
{black,
Tube[Line[{{1,0,0},{len,0,0}}],.03],
Tube[Line[{{Cos[ang],-Sin[ang],0},len{Cos[ang],-Sin[ang],0}}],.03],
Arrowheads[.04],arc[ang],
Text[Style[ToString[NumberForm[N@ang/Degree,{3,1}]]<>"\[Degree]",fontSize,Black,Background->GrayLevel[1,.8],FontFamily->fontFamily],1.7{Cos[ang/2],-Sin[ang/2],0},{-.5,-.5}]
}
];

(* ::Section:: *)
(*Waves*)

(* ::Input::Initialization:: *)
waveCircular[ampl_,phase_,length_:dist]:=Module[{c=2\[Pi] /dist 5,aux},
aux=ParametricPlot3D[{ampl Sin[c t-phase],ampl Cos[c t-phase],t},{t,0,length}];
aux=First@Cases[InputForm[aux],_Line,Infinity];
{Red,Tube[aux,.05]}
];

(* ::Input::Initialization:: *)
wave[ampl_,phase_,length_:dist]:=Module[{c=2\[Pi] /dist 5,aux},
aux=ParametricPlot3D[{ampl Sin[c t-phase],0,t},{t,0,length}];
aux=First@Cases[InputForm[aux],_Line,Infinity];
{Red,Tube[aux,.05]}
];

(* ::Section:: *)
(*Time evolution*)

(* ::Input::Initialization:: *)
evolAngleRezoom=Interpolation[{{0,ang1},{.5,ang12},{1,ang2}},InterpolationOrder->2];

(* ::Input:: *)
(*(*Plot[evolAngleRezoom[x],{x,0,1}]*)*)

(* ::Input::Initialization:: *)
timeEvolution[t_]:=Module[{ang,pt,ctr,len,ypos,rot,lena,
t1=0.1,t2=0.3,t3=0.5,t4=0.7,t5=0.9,ypos1=-2.1,ypos2=0,rot1=0,rot2=90Degree,pt1={2,4,4},pt2={2,2,4}+{0.18,0,2dist},ctr1={0,0,0.3},ctr2={0.18,0,2dist},len1=dist,len2=2dist-outerthick,len3=3dist,len4=2dist-innerthick-0.01,lena1=0,lena2=dist
},

Which[
t<t1,{ang1,pt1,ctr1,len1,ypos1,rot1,lena1},

t1<=t<t2,{
evolAngleRezoom[Rescale[t,{t1,t2},{0,1}]],
pt1+Rescale[t,{t1,t2},{0,1}](pt2-pt1),
ctr1+Rescale[t,{t1,t2},{0,1}](ctr2-ctr1),
Rescale[t,{t1,t2},{len1,len2}],
ypos1,
rot1,
lena1
},

t2<=t<t3,{ang2,pt2,ctr2,len2,Rescale[t,{t2,t3},{ypos1,ypos2}],rot1,lena1},

t3<=t<t4,{ang2,pt2,ctr2,Rescale[t,{t3,t4},{len2,len3}],ypos2,rot1,lena1},

t4<=t<t5,{ang2,pt2,ctr2,len4,ypos2,Rescale[t,{t4,t5},{rot1,rot2}],lena2},

t5<=t,{ang2,pt2,ctr2,len4,ypos2,rot2,lena2}
]

]

(* ::Section:: *)
(*Scene*)

(* ::Input::Initialization:: *)
scene[t_]:=Module[{ang,pt,ctr,len,ypos,rot,lena},

{ang,pt,ctr,len,ypos,rot,lena}=timeEvolution[t];
Graphics3D[{
{
filter,
{Red,EdgeForm[None],
{Opacity[.5],Cylinder[{{0,0,-dist},{0,0,-1.01innerthick/2}},.6innerrad]},
{Opacity[0.25],Cylinder[{{0,0,1.01innerthick/2},{0,0,len}},.6innerrad]}
},
Translate[waveCircular[.55innerrad ,-5t],{0,0,-dist}],
Translate[wave[1/Sqrt[2] .55innerrad ,-5t,len],{0,0,0}]
},
{
Translate[reticule[rot],{0,ypos,2dist}],
Translate[Rotate[filter,-rot,{0,0,1}],{0,ypos,2dist}],
If[lena!=0,{Red,EdgeForm[None],
Opacity[0.25Cos[rot]^2],Cylinder[{{0,0,2dist+1.01innerthick/2},{0,0,2dist+lena}},.6innerrad],
Opacity[Cos[rot]],Translate[Rotate[wave[1/Sqrt[2] .55innerrad Cos[rot],-5t,len/2],-rot,{0,0,1}],{0,0,2dist}]
},{}]

}
},
Boxed->False,Lighting->"Neutral",
PlotRange->{2.1{-.6,1},2{-2,0.6},1.05dist{-1,4}},
ViewVector->{pt,ctr},ViewAngle->ang,ViewVertical->{1,0,0}
]]

(* ::Section:: *)
(*Export*)

(* ::Input:: *)
(*(*Manipulate[scene[t],{{t,.878},0,1,Appearance\[Rule]"Open"}]*)*)

(* ::Input:: *)
(*{time,frames}=AbsoluteTiming[ParallelTable[Rasterize[scene[t],RasterSize->500],{t,0,1,.01}]];*)
(*time*)

(* ::Input:: *)
(*SetDirectory[NotebookDirectory[]]*)
(*Export["scene.gif",frames,AnimationRepetitions->Infinity,"DisplayDurations"->.1]*)

(* ::Input:: *)
(*SystemOpen[%]*)

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current12:54, 29 August 2021Thumbnail for version as of 12:54, 29 August 2021500 × 500 (3.56 MB)JozumBjada (talk | contribs)Cross-wiki upload from cs.wikipedia.org

You cannot overwrite this file.

There are no pages that use this file.

File usage on other wikis

The following other wikis use this file:

Metadata

This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.

Retrieved from "https://commons.wikimedia.org/w/index.php?title=File:Two_polarizers_animation.gif&oldid=766964650"