I, the copyright holder of this work, hereby publish it under the following license:

This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.

You are free:

• to share – to copy, distribute and transmit the work
• to remix – to adapt the work

Under the following conditions:

• attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
• share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue

kill(all);
remvalue(all);

/*------------- functions definitions ---------*/


/* conformal map  from circle to cardioid ( boundary
 of period 1 component of Mandelbrot set */
F(w):=w/2-w*w/4;

/* 
circle D={w:abs(w)=1 } where w=l(t,r) 
t is angle in turns ; 1 turn = 360 degree = 2*Pi radians 
r is a radius 
*/
ToCircle(t,r):=r*%e^(%i*t*2*%pi);

GiveC(angle,i_radius):=block(
 [w,c],
 /* point of  unit circle    */
 w:ToCircle(angle,i_radius),  /* point of circle */
 c:float(rectform(F(w))),    /* point on boundary of period 1 component of Mandelbrot set */
 return(c)
)$
















/* function */
f(z):=z^2 + c;


define (df(z), diff(f(z), z, 1))$



/* f(z) is used as a global function
   I do not know how to put it as a argument */

GiveOrbit(z0,OrbitLength):=
block(
 [z,Orbit],
 z:z0,
 Orbit:[z0], 
 for i:1 thru OrbitLength step 1 do
        ( z:expand(f(z)),
          Orbit:endcons(z,Orbit)),
         
 return(Orbit) 

)$

/* 
converts complex number z = x*y*%i 
to the list in a draw format:  
[x,y] 
*/
d(z):=[float(realpart(z)), float(imagpart(z))]$

ToPoints(myList):= points(map('d,myList))$


/* give Draw List from one point*/
ToPoint(z):=points([d(z)])$



cturn(z):=block(
	[t],
	t : carg(z),
	t : t/(2*%pi),
	if (t<0.0) then t:t+1.0,
	return(float(t))
)$





compile(all);

/* -----const values -------  */
iLength:100000; /* number of points to draw */
angle : 0.05730221983248095$
/* 0.9999653149513355$  */
r :1.0; 

c: GiveC(angle,r)$
zcr:0.0$

/* ------------- main  = computations -----------------*/

 /* compute fixed points */
 
 alfa:float(rectform((1-sqrt(1-4*c))/2))$ /* other fixed point */
 
 m: df(alfa);
 
 print("multiplicator(alfa)=", float(rectform(m)))$
 print("stability(alfa)=",  cabs(m))$
 print("internal angle(alfa)=", cturn(alfa))$
 



 Orbit:GiveOrbit(zcr,iLength)$
 


Orbit:ToPoints(Orbit)$
zcr:ToPoint(zcr)$

alfa:ToPoint(alfa)$

/*-----------------------------------------------------------------------*/


path:"~/Dokumenty/cr/gif/"$  /*  if empty then file is in a home dir */

load(draw); /* ( interface to gnuplot ) by Mario Rodriguez Riotorto http://www.telefonica.net/web2/biomates */

draw2d(
    title = concat("Critical orbit for f(z)=z^2 +", string(c)),
    terminal  = png,
    user_preamble = "set size square; set key left top;", /*    */
    file_name = concat(path ,string(iLength),"_", string(r)),
    dimensions = [1000,1000],    /* Since Maxima 5.23, pic_width and pic_height are deprecated. */
    
    xrange = [-0.1,0.8],
    yrange = [-0.1,0.8],
    
    xlabel     = "z.re ",
    ylabel     = "z.im",

    
    
    point_type    = 7, 
    points_joined = false,
    point_size    = 0.8,
    key=" critical orbit ",
    color             =red,
    Orbit,
   
    point_size    = 1.2,
    key= "critical point",
    color           = blue,
    zcr,
    
    

    key= "fixed point",
    color           = black,
    alfa

 );