reset
set term svg size 700,700 fname 'Verdana' fsize 12
set size square .9
set lmargin at screen .15
set tmargin at screen .9
set angles degrees
unset key
unset border
set polar
set rtics ("" 0, "0" 1, "1" 2, "2" 3, "3" 4, "4" 5, "5" 6, "6" 7)
set rrange [1e-2:7]
unset xtics
unset ytics
set grid polar 30 lt 1 lc 0 lw 0.3
 
set_label(x, text) = sprintf("set label '%s' at (8*cos(%f)), (8*sin(%f)) center", text, x, x)
 
eval set_label(0, "Methanol")        #7
eval set_label(30, "Aceton")         #7
eval set_label(60, "Acetonitril")    #7
eval set_label(90, "Dichlormethan")  #1
eval set_label(120, "Schwefelkohlenstoff") #1,5
eval set_label(150, "Toluol")        #0
eval set_label(180, "Diethylamin")   #1,5
eval set_label(210, "Tetrahydrofuran") #1,5
eval set_label(240, "Ethylacetat")   #4
eval set_label(270, "n-Heptan")      #4
eval set_label(300, "NaOH")          #7
eval set_label(330, "H2SO4")         #7
 
set output 'butyl.svg'
plot "-" u 1:2 t "Butylkautschuk" w l lt 1 lw 3 lc rgb 0xFF0000
0 7
30 7
60 7
90 7
120 2
150 2.5
180 1
210 2.5
240 2.5
270 5
300 1
330 7
360 7
e
unset output